下面是一個對51實驗板配套的紅外線遙控器的解碼程序，它可以把紅外遙控器每一個按鍵的鍵值讀出來，并且通過實驗板上P1口的8個LED顯示出來，在解碼成功的同時并且能發出“嘀嘀嘀”的提示音。
;=================================================
; 紅外遙控接收
;=================================================
; ew51仿真編程器 配套實驗板學習例程
;
; 中山單片機學習網 智佳科技 逸風
;
; http://www.zsMCU.com
; E-mail:info@zsmcu.com
;=================================================
ORG 0000H
MAIN:
JNB P2.2,IR ;遙控掃描
LJMP MAIN ;在正常無遙控信號時，一體化紅外接收頭輸出是高電平，程序一直在循環。
;=================================================
; 解碼程序
IR:
;以下對遙控信號的9000微秒的初始低電平信號的識別，波形見圖５。
MOV R6,#10
IR_SB:
ACALL DELAY882 ;調用882微秒延時子程序
JB P2.2,IR_ERROR ;延時882微秒后判斷P2.2腳是否出現高電平如果有就退出解碼程序
DJNZ R6,IR_SB ;重復10次，目的是檢測在8820微秒內如果出現高電平就退出解碼程序
;識別連發碼，和跳過4.5ma的高電平。
JNB P2.2, $ ;等待高電平避開9毫秒低電平引導脈沖
ACALL DELAY2400
JNB P2.2,IR_Rp ;這里為低電平，認為是連發碼信號，見圖６。
ACALL DELAY2400 ;延時4.74毫秒避開4.5毫秒的結果碼
;以下32數據碼的讀取 ，０和１的識別 請看圖２
MOV R1,#1AH ;設定1AH為起始RAM區
MOV R2,#4
IR_4BYTE:
MOV R3,#8
IR_8BIT:
JNB P2.2,$ ;等待地址碼第一位的高電平信號
LCALL DELAY882 ;高電平開始后用882微秒的時間尺去判斷信號此時的高低電平狀態
MOV C,P2.2 ;將P2.2引腳此時的電平狀態0或1存入C中
JNC IR_8BIT_0 ;如果為0就跳轉到IR_8BIT_0
LCALL DELAY1000
IR_8BIT_0:
MOV A,@R1 ;將R1中地址的給A
RRC A ;將C中的值0或1移入A中的最低位
MOV @R1,A ;將A中的數暫時存放在R1中
DJNZ R3,IR_8BIT ;接收地址碼的高8位
INC R1 ;對R1中的值加1，換下一個RAM
DJNZ R2,IR_4BYTE ;接收完16位地址碼和8位數據碼和8位數據，
;存放在1AH/1BH/1CH/1DH的RAM中
;解碼成功
JMP IR_GOTO
IR_Rp:
;這里為重復碼執行處
;按住遙控按鍵時，每過108ms就到這里來
JMP IR_GOTO
IR_ERROR:
;錯語退出
LJMP MAIN ;退出解碼子程序
;=================================================
;遙控執行部份
IR_GOTO:
;這里還要判斷1AH和1BH 兩個系統碼或用戶碼，用于識別不同的遙控器
;MOV A,1AH
;CJNE A,#xxH,IR_ERROR ;用戶碼１不對則退出
;MOV A,1BH
;CJNE A,#xxH,IR_ERROR ;用戶碼２不對則退出
;判斷兩個數據碼是否相反
MOV A,1CH
CPL A
CJNE A,1DH,IR_ERROR ;兩個數據碼不相反則退出
;遙控執行部份
;MOV A,1DH ;判斷對應按鍵
;CJNE A,#xxH,$+6
;LJMP -à跳到對應按鍵執行處
;CJNE A,#xxH,$+6
;LJMP -à跳到對應按鍵執行處
;.
MOV P1,1DH ;將按鍵的鍵值通過P1口的8個LED顯示出來!
CLR P2.3 ;蜂鳴器鳴響－嘀嘀嘀－的聲音，表示解碼成功
LCALL DELAY2400
LCALL DELAY2400
LCALL DELAY2400
SETB P2.3 ;蜂鳴器停止
;清除遙控值使連按失效
MOV 1AH,#00H
MOV 1BH,#00H
MOV 1CH,#00H
MOV 1DH,#00H
LJMP MAIN
;=================================================
; 延時子程序
;=============================882
DELAY882: ;1.085x ((202x4)+5)=882
MOV R7,#202
DELAY882_A:
NOP
NOP
DJNZ R7,DELAY882_A
RET
;=============================1000
DELAY1000: ;1.085x ((229x4)+5)=999.285
MOV R7,#229
DELAY1000_A:
NOP
NOP
DJNZ R7,DELAY1000_A
RET
;=============================2400
DELAY2400: ;1.085x ((245x9)+5)=2397.85
MOV R7,#245
DELAY2400_A:
NOP
NOP
NOP
NOP
NOP
NOP
NOP
DJNZ R7,DELAY2400_A
RET
END
66821730(技術支持)
